use strict and my $wibble are not seen by include.pl. do s executes it in a different lexical scope.

That means that $wibble = "fred"; actually does $main::wibble = "fred"; (assuming main is the current package).

Because of the my $wibble (not because of use strict), the main program's $wibble refers to a lexical var and not to $main::wibble. If you were to print $main::wibble, you'd see "fred".

The most straightforward way to solve the problem is to use eval instead of do. eval runs code in the same lexical scope as the eval itself (instead of creating an entirely new scope like do), so the code sees and obeys directives such as use strict and my $wibble. 

use strict;
use warnings;

my $include_file = 'include.pl';

my $wibble;

eval do {
   open(my $fh, '<', $include_file)
      or die("Unable to open include \"$include_file\": $!\n");
   local $/;
   <$fh>
};
die $@ if $@;

print $wibble;

[download]
# include.pl

$wibble = 'fred';

# Uncommenting the following line causes a strict error.
#$wobble = 'joe';

[download]

In reply to Re: strict/do question by ikegami
in thread strict/do question by dch

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.