Maybe you could use $^S to see if you're in an eval. For example,

DieWithCode.pm: 

use strict;
use warnings;

package DieWithCode;

BEGIN {
   our @EXPORT = 'die_with_code';
   require Exporter;
   *import = \&Exporter::import;
}

use Carp qw( carp croak );

sub die_with_code {
   my $code = shift(@_);

   if ($^S) {
      croak(@_);
   } else {
      carp(@_);
      exit($code);      
   }
}

1;

[download]

Test script 587042.pl: 

use strict;
use warnings;

use DieWithCode qw( die_with_code );

$|=1;

eval { die_with_code(4, "Foo"); };
print "Caught: $@" if $@;

eval { die_with_code(5, "Bar\n"); };
print "Caught: $@" if $@;

s/\\n/\n/g for @ARGV;
die_with_code(@ARGV);

[download]

Test runs: 

>perl 587042.pl 6 "Baz"
Caught: Foo at 587042.pl line 9
Caught: Bar
Baz at 587042.pl line 16

>echo %ERRORLEVEL%
6

>perl 587042.pl 7 "Boo\n"
Caught: Foo at 587042.pl line 9
Caught: Bar
Boo

>echo %ERRORLEVEL%
7

[download]

Update: Made it into a module so carp and croak would print the right line number.

In reply to Re: Die and Exit Codes by ikegami
in thread Die and Exit Codes by pileofrogs

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.