It's a reasonable question, but you still haven't posted any code, so you may indeed get dinged. In the monestary, code begets code. If your original post had included some kind of code, you probably would have had a lot more input from monks and might have a working solution by now.

On to your question.

The documentation for the get() method in Net::FTP mentions that for get(REMOTE_FILE[,LOCAL_FILE,WHERE]), LOCAL_FILE may be a filename or a filehandle. If you open() a filehandle for writing you can write as many index files as you want and they will be concatenated in the order they were written. WHERE is optional in the method, but you could use it to skip the first unnecessary header bytes of the index file. You can also open() an "in memory" filehandle that is held as a scalar. This is probably what you want. Here is a quick script that grabs the index files for all 4 quarters in 2 years and writes the concatenated indices to a file. I have also included a commented out option to use a scalar as a filehandle. This is what you will probably ultimately want to use.

#!/usr/bin/perl

use strict;
use warnings;

use Net::FTP;

my $host         = "ftp.sec.gov";
my $username     = 'anonymous';
my $password     = 'yourmail@domain.com';
my $indexdir     = '/edgar/full-index';
my @years        = qw/2005 2006/;
my @quarters     = qw/QTR1 QTR2 QTR3 QTR4/;
my $indexbyfirm  = 'company.idx';
my $indexoutfile   = "./complete_index";

##This opens an "in memory" filehandle as a scalar
#open my $indexsave, '>', \ my $pseudo_file
#    or die "Couldn't open memory handle: $!"; 

open my $indexsave, '>', $indexoutfile
    or die "Couldn't open filehandle: $!";

my $ftp= Net::FTP->new("$host",
            Timeout => 30,
            Debug   => 1)
    or die "Couldn't connect: $@\n";

$ftp->login($username, $password)
    or die "Couldn't authenticate.\n";

for my $year (@years) {
    for my $quarter (@quarters) {
        
        $ftp->cwd("$indexdir/$year/$quarter")
            or die "Couldn't change directories : $!\n";
        
        $ftp->get($indexbyfirm, $indexsave)
             or die "Couldn't fetch $indexbyfirm : $!\n";
    }
}

## You can work with the "in memory" file like any scalar
# print "$pseudo_file";

$ftp -> quit();

[download]

In reply to Re^5: Making an array from a downloaded web page by moklevat
in thread Making an array from a downloaded web page by malomar66

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.