While the case of '--' and ';' seems to be a matter of debate and jocose comment, you might like to know that you can switch case sensitivity on and off in different parts of a regular expression. You would use constructs like (?i), (?-i), (?i:text) and (?-i:text). The first two switch case insensitivity on and off respectively. The second two just apply their effect, insensitive or sensitive respectively, to the text inside the parentheses. Here is a contrived example that uses a precompiled (qr{ ...}) regular expression that also uses extended syntax, the x, to allow comments and white space inside the expression.

use strict;
use warnings;

my @strings = (
   q{catFiSHcake},
   q{DogFISHcAkE},
   q{cATfishCake},
   q{caTFISHcaKE});

my $rxMixed = qr
   {(?xi)           # use extended syntax and
                    #   make case insensitive
       (?:cat|dog)  # non-capture alternation
                    #   of cat or dog
       (?-i:FISH)   # FISH, case sensitive
                    #   inside parentheses
       cake         # cake, case insensitive
                    #   again
   };

foreach my $string ( @strings )
{
    print
       qq{$string: },
       $string =~ $rxMixed
       ? qq{Match\n}
       : qq{No match\n};
}

[download]

Here's the output.

catFiSHcake: No match
DogFISHcAkE: Match
cATfishCake: No match
caTFISHcaKE: Match

[download]

I hope this is of interest.

Cheers,

JohnGG

In reply to Re^3: Making a regex case insensitive by johngg
in thread Making a regex case insensitive by Win

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.