I have a solution, but it requires making a couple of changes to Parallel::ForkManager.

Solution:

use strict;
use warnings;

use Parallel::ForkManager qw( );

my @data = (
   ...
);

my @tasks = (
   sub { printf("%s\n",                 $_[0]); },
   sub { exec('/home/working/perl1.pl', $_[0]); },
   sub { exec('/home/perl2.pl',         $_[0]); },
);

{
   my $task_id;
   my @idle = (0..$#tasks);
   my %alloc;

   my $pm = Parallel::ForkManager->new(scalar(@tasks));

   $pm->run_pre_fork(sub {
      $task_id = shift(@idle);
   });

   $pm->run_on_start(sub {
      my ($pid) = @_;
      $alloc{$pid} = $task_id;
   });

   $pm->run_on_finish(sub {
      my ($pid) = @_;
      push(@idle, delete($alloc{$pid}));
   });

   foreach my $data (@data) {
      my $pid = $pm->start and next;
      $tasks[$task_id]->($data);
      $pm->finish;
   }
}
[download]

Changes to site/lib/Parallel/ForkManager.pm:

• Change

    $s->wait_children;
    if ($s->{max_proc}) {
      my $pid=fork();
  [download]

  in start to

    $s->wait_children;
    $s->pre_fork;
    if ($s->{max_proc}) {
      my $pid=fork();
  [download]

• Add

  sub run_pre_fork { my ($s,$code)=@_;
    $s->{pre_fork}=$code;
  }
  
  sub pre_fork { my ($s)=@_;
    $s->{pre_fork}->() if ref($s->{pre_fork}) eq 'CODE';
  }
  [download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.