Would it be possible to do the actual re-defining at a later stage (say, CHECK or INIT)?

Something like this: 

package ImportLater;

use strict;
use warnings;

our %overrides;

sub import {
    my $class = shift;
    my @functions = @_;
    my $cpkg  = caller;

    $overrides{$cpkg} = \@functions;
    return;
}

# For demonstration purposes only. This is where you'd do your stuff
sub override_functions {
    for my $pkg( keys %overrides ) {
        print "$pkg: @{$overrides{$pkg}}\n";

        foreach my $func ( @{$overrides{$pkg}} ) {
            no warnings 'redefine';
            no strict 'refs';
            my $orig = \&{"$pkg\::$func"};
            *{"$pkg\::$func"} = sub { 
                print "before $func\n";
                return $orig->(@_);
            };
        }
    }
}

INIT {
    override_functions();
}

1;

[download]
Use it like this: 
#!/usr/bin/perl

use strict;
use warnings;

use ImportLater qw/ foo bar /;

sub foo {
    print "I'm foo";
}

foo();

[download]
Running that outputs: 
main: foo bar
before foo
I'm foo

[download]

In reply to Re: unimport warnings in another package by rhesa
in thread unimport warnings in another package by wazzuteke

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.