Since the procedure is described in detail at the site mentioned above, I'll try to be as brief as possible here:

1. Alice and Bob choose a secret key each, IdA and IdB, consisting of 28 digits long numbers picked up randomly, and concordate a public key Sh wich is 50 digits long one.
2. Alice multiplies IdA by Sh and cuts the 11 leftmost and rightmost digits, to obtain MidA, consisting of the central ones only. It is this "cutting" operation that the authors claim to be the "one way function" that makes the algorithm secure. Bob does the same with Idb to obtain MidB.
3. They now exchange MidA and MidB.
4. Alice multiplies her IdA by MidB she just got to obtain a number SecA. Similarly Bob obtains SecB.
5. Now, the authors claim that although Alice doesn't know SecB and Bob doesn't know SecA, the digits from the 46th to the 55th (counting from the leftmost) are always the same for both numbers and can thus be used as a password of length ten.

To be fair, the algorithm is supposed to be fairly general and doesn't strictly rely on base 10 and on the lengths I gave, but more general ones can be chosen: indeed the authors describe four possible "standards", called XEVRON-T1 through XEVRON-T4 of which the one I described above is the simplest.

#!/usr/bin/perl

use strict;
use warnings;
use Math::BigInt;

sub input;

my @id;
push @id, input "Alice's secret key" => 28;
push @id, input "Bob's secret key" => 28;
my $sh=input "the public key" => 50;

my @mid=map $_*$sh, @id;
for (@mid) {
    substr $_, 0,   11 => '';
    substr $_, -11, 11 => '';
}

my ($pwa,$pwb)=map { substr $id[$_]*$mid[1-$_], -55, 10 } 0,1;

print  $pwa eq $pwb ?
  "The passwords match: <$pwa>\n" :
  "The passwords don't match:\n<$pwa>\n<$pwb>\n";

sub input {
    local $\="\n";
    my ($msg,$n)=@_;
    my $m=$n-1;
    print "Please input $msg, a $n digits number, ",
      "or <r> for a random one";
    my $in;
    {
        print '-' x $n;
        chomp($in=<STDIN>);
        if (lc $in eq 'r') {
            $in = 1 + int rand 9;
            $in .= int rand 10 for 1..$m;
            print $in;
            last;
        }
        print "Wrong input, retry" and redo
          unless $in =~ /^[1-9][0-9]{$m}$/;
    }
    print '';
    Math::BigInt->new($in);
}

__END__
[download]