Sorry, I have nothing to contribute to tracking down your recursion error. I found the riddle intriguing and tried an independent solution. Here it is: 
my $target = 24;
my @nums = ( 1, 3, 4, 6);
for ( solve( $target, @nums) ) {
    my $val = eval;
    print "$_ = $val\n";
}

sub solve {
    my ( $target, @nums) = @_;
    my @sols;
    for my $i ( 0 .. $#nums ) {
        my @rem = @nums;
        my $first = splice @rem, $i, 1;
        if ( @rem ) {
            for ( complements( $target, $first) ) {
                my ( $op, $try) = @$_;
                push @sols, map "$first $op $_",
                    map m{[-+*/]} ? "($_)" : $_,
                    solve( $try, @rem);
            }
        } else {
            push @sols, $first if $first eq $target; # sic!
        }
    }
    return @sols;
}

sub complements {
    my ( $t, $x) = @_;
    (
        [ '+', $t - $x],
        [ '-', $x - $t],
        $x ? [ '*', $t/$x] : (),
        $t ? [ '/', $x/$t] : (),
    );
}

[download]
Not thoroughly tested, but it finds the solution 
6 / (1 - (3 / 4)) = 24

[download]
Anno

In reply to Re: Number from given digits puzzle by Anno
in thread Number from given digits puzzle by ambrus

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.