Ok, looked a little longer at your code and figure I see what you are trying to do. The following probably addresses your immediate problem:

use strict;
use warnings;

use XML::Twig;

use vars qw (%PARAMS);
do 'noname1.pl';

for my $key (keys %PARAMS) {
    my $val = $PARAMS{$key}; # Need var because sub turns it into a cl
+osure
    
    $PARAMS{$key} = sub {upd_param (@_, $val)};
}

my $twigT= new XML::Twig(
    twig_roots   => \%PARAMS,
    twig_print_outside_roots => 1,              
    );

$twigT->parse (do {local $/; <DATA>});
$twigT->purge; #probably not needed

sub upd_param {
    my ($t, $param,$new_param) = @_;
    my $item = defined($new_param)? $new_param:$param->text;
    
    $param->set_text($item);                # change it
    $param->print;                          # print updated value
    $t->purge;                              # free the memory
}

__DATA__
<task>
    <params>
        <CellRefinementLevel></CellRefinementLevel>
    </params>
</task>

[download]

Prints:

<task>
    <params>
        <CellRefinementLevel>7</CellRefinementLevel>
    </params>
</task>

[download]

given a file noname1.pl containing:

$PARAMS{'CellRefinementLevel'}=7;
$PARAMS{'GridCellSizeInXDirection'}=100;
$PARAMS{'GridCellSizeInYDirection'}=100;

[download]

However the same mapping could be provided using a rather less frightening text file containing:

CellRefinementLevel=7
GridCellSizeInXDirection=100
GridCellSizeInYDirection=100

[download]

if the use vars and do lines are replaced with:

@ARGV = 'noname.txt'; # omit if config file passed on the command line
my %PARAMS = map {chomp; split '='} grep {length} <>;

[download]
DWIM is Perl's answer to Gödel

In reply to Re: XML::twig using a hash in twig_roots by GrandFather
in thread XML::twig using a hash in twig_roots by bladestonight

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.