Because your second regex (if ($day=~/\d{1}/)) clobbers $3. I'd rework the code somewhat to:

use strict;
use warnings;

my %datehash = (
    jan => 1, feb => 2, mar => 3, apr => 4, may => 5, jun => 6,
    jul => 7, aug => 8, sep => 9, oct => 10, nov => 11, dec => 12
    );

while (<DATA>) {
    chomp;
    my $data = lc $_;
    
    next unless $data =~ /(\D{3}) \s* (\d{1,2}) \s* (\d{4})/x;
    next unless exists $datehash{$1};

    my $month = $datehash{$1};

    printf "%04d%02d%02d\n", $3, $month, $2;
}
    
__DATA__
Oct 16 2004 11:09:19:943AM
Mar 3 2007 10:30:31:170PM

[download]

Prints:

20041016
20070303

[download]

Note the use of \s to match any white space and that a greedy match is used because it makes no difference in this context. Note too that the /x flag is used so that white space can be used in the regex to make the different parts more obvious.

printf is a cleaner way of generating the string. If you want the assign the result to a variable use sprintf instead.

For future reference it is worth giving a stand alone runnable sample such as this so others can reproduce your problem easily.

DWIM is Perl's answer to Gödel

In reply to Re: Pattern matching for extracting dates by GrandFather
in thread Pattern matching for extracting dates by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.