package Tie::NumRange;

# (initial, low, high)
sub TIESCALAR {
  my $class = shift;
  my $self = bless [ @_ ], $class;
  $self->STORE($_[0]);  # just in case
  return $self;
}

sub STORE {
  my ($self,$val) = @_;

  return $self->[0] = $self->[1] if
    defined($self->[1]) and
    $self->[1] > $val;

  return $self->[0] = $self->[2] if
    defined($self->[2]) and
    $self->[2] < $val;

  return $self->[0] = $val;
}

sub FETCH { $_[0][0] }

1;
[download]

Very simple concept really, which I got from $code_or_die's recent node for shifting RGB values. Here's an example use:

use Tie::NumRange;
my ($r,$g,$b);
tie $r, Tie::NumRange => (0, 0, 255);
tie $g, Tie::NumRange => (0, 0, 255);
tie $b, Tie::NumRange => (0, 0, 255);

$r = 100;  # fine
$g = 200;  # fine
$b = 300;  # set to 255

$b -= 150;  # fine, is now 105
$g -= 150;  # fine, is now 50
$r -= 150;  # set to 0
[download]

The arguments to tie() are the variable, the class, the inital value, the floor, and the ceiling. To make a number with no least value, send undef as the floor (likewise for the ceiling).

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.