First of all, you can easily dump structures using Data::Dumper. No need to roll out your custom subroutine.

You can do some complicated dereferencing/referencing: 

use strict;
use warnings;

my $str = "One:Two:Three:four, One:Two:3:4, One:2:3:4, One:2:three";

my %hash;

my @defs = split(/\s*,\s*/, $str);  # Use Text::CSV?
foreach my $def (@defs) {
   my @keys = split(/:/, $def);
   my $val = pop(@keys);
   my $p = \\%hash;
   while (@keys) { $p = \($$p->{shift(@keys)}); }
   $$p = $val;
}

require Data::Dumper;
print(Data::Dumper::Dumper(\%hash));

[download]

Or you can use tye's Data::Diver module: 

use strict;
use warnings;

use Data::Diver qw( DiveVal );

my $str = "One:Two:Three:four, One:Two:3:4, One:2:3:4, One:2:three";

my %hash;

my @defs = split(/\s*,\s*/, $str);  # Use Text::CSV?
foreach my $def (@defs) {
   my @keys = split(/:/, $def);
   my $val = pop(@keys);
   DiveVal(\%hash, map { \$_ } @keys) = $val;
}

require Data::Dumper;
print(Data::Dumper::Dumper(\%hash));

[download]

The second snippet is untested.

Important! The first snippet doesn't check for bad data such as 'one:orange, one:apple:car', but it would be easy to add a check. I don't know how Data::Diver deals with that.

In reply to Re: parsing a parent-child syntax to make a hash by ikegami
in thread parsing a parent-child syntax to make a hash by argv

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.