I don't know anything about Algorithm::Loops, but given your code above, there is no need for the intermediate array @list. Instead, you can work out uniqueness as you go by using the keys of a hash:

#!/usr/bin/perl -w
use strict;
use Algorithm::Loops qw(NestedLoops);


my @symbol = (
   [ 'a', 'b', 'c' ],
   [ 'a', 'b', 'c'  ],
   [ 'a', 'b', 'c'  ],
   [ 'c', 'd', 'e'  ],
);

my $iter = NestedLoops(\@symbol);
my %seen;

while (my @list = $iter->()) {
    my $listString = join ('',sort @list);
    $seen{$listString}++
}

my @sortedUniq = sort (keys %seen);

foreach my $sortedUniq (@sortedUniq) {
    print $sortedUniq,"\n";
}

[download]

Clint

UPDATE - Benchmarks added

I compared the array method to the hash method, both for data that was all the same, and for data that was completely different, the results were: 


                 Rate array_diff array_same  hash_diff  hash_same
    array_diff  916/s         --       -10%       -16%       -25%
    array_same 1012/s        11%         --        -7%       -18%
    hash_diff  1092/s        19%         8%         --       -11%
    hash_same  1229/s        34%        21%        13%         --

[download]

Code for benchmarks:


#!/usr/bin/perl -w
use strict;
use Algorithm::Loops qw(NestedLoops);
use Benchmark qw(cmpthese);


my @same = (
   [ 'a', 'a', 'a' ],
   [ 'a', 'a', 'a'  ],
   [ 'a', 'a', 'a'  ],
   [ 'a', 'a', 'a'  ],
);

my @different = (
   [ 'a', 'b', 'c' ],
   [ 'd', 'e', 'f'  ],
   [ 'g', 'h', 'i'  ],
   [ 'j', 'k', 'l'  ],
);



sub array {
    my $symbols = shift;
    my @all;
    my $iter = NestedLoops($symbols);
    my @list;
    while (@list = $iter->()) {
        my @sortedList = sort @list;
        my $listString = join ('',@sortedList);
        push @all, $listString;
        }

    my @uniq = keys %{{ map { $_ => 1 } @all }};
    my @sortedUniq = sort (@uniq);

}

sub hash {
    my $symbols = shift;
    my $iter = NestedLoops($symbols);
    my %seen;

    while (my @list = $iter->()) {
        my $listString = join ('',sort @list);
        $seen{$listString}++
    }

    my @sortedUniq = sort (keys %seen);
}

cmpthese(5000, {
    array_same => sub { array(\@same)},
    array_diff => sub { array(\@different)},
    hash_same  => sub { hash(\@same)},
    hash_diff  => sub { hash(\@different)},
});

[download]

In reply to Re: Efficient Unique Nested Combinations by clinton
in thread Efficient Unique Nested Combinations by FFRANK

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.