You can compile the code for methods in a package other than the one used to look up methods (the one matching the class name), then you can put non-method utilities in that non-class package and use them directly w/o inheritance and without poluting your "method name" namespace.

package My::Class::SubClass;
require My::Class::Base;
@ISA= qw( My::Class::Base );

package My::Class::SubClass::_code;
# Import common non-methods:
My::Class::Base::_code->import( qw( _utilSub _timestamp ) );

# Export below methods to My::Class::SubClass:
for(  grep !/^_/, keys %{ __PACKAGE__ . "::" }  ) {
    *{"My::Class::SubClass::".$_}= \&$_
        if  defined &$_;
}

use strict;

sub new {
    my $us= shift @_;
    ...
    $us->someBaseMethod( @works );
    _utilSub( _timestamp() );
    ...
}
[download]

Then you don't have to try to guess whether the first argument is an object or not. Perhaps more importantly, you don't have to worry about your users being confused when they access a utility function that has nothing to do with the object via a simple $obj->_timestamp(), since that would tell them that there is no _timestamp() method.

If you don't like the underscore, then you can list which methods to export rather than just exporting all subroutines that don't have a leading underscore.

Just because Perl 5 doesn't include a feature for distinguishing methods from non-methods, doesn't mean you have to throw all of those different items into the same namespace.

Note that this breaks SUPER:: and some naive OO doohickeys that try to rely on caller (which doesn't currently provide a proper class name for such uses).

If you want your users to be able to access the util sub as a method, then you can use this same technique (of compiling methods into a package other than the one having the name of the class) to provide both a method and non-method version without having to try to guess whether the first argument is an object:

package My::Class::Base;
use vars qw( $VERSION );
$VERSION= 1.001_002;

package My::Class::Base::_code;
use vars qw( @EXPORT_OK );
BEGIN {
    require Exporter;
    *import= \&Exporter::import;
    @EXPORT_OK= qw( _utilSub _timestamp );
}

use strict;

sub _timestamp {
    # non-method code
}

# Method version:
*My::Class::Base::_timestamp= sub {
    shift @_;
    return _timestamp();
}
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.