Without seeing your "somefile.txt" I'm not sure what you are doing to get your $word. Certainly, the second chomp is superfluous as you can't remove the line terminator twice. My code below is the equivalent of yours except that I don't do the final chop as I can't tell whether it was necessary; it's easy enough to add back in. I perform the parsing of "somefile.txt" in a BEGIN {...} block before going on to append to the lines in the "address" file.

moritz points out that it can be a bad idea to edit a file in place. Perl does, however, have a handy -i flag for in-place editing which, if given an extension, will preserve your original file with that extension, the modified file taking the original name. Given a spurious "tcp" file and an "address" file

$ cat spw638403.txt
aajkaj  XYZtcpHJHKtcpKJHKH
ashhgdasjh    JKHKJHtcpUUHtcpHDKJHtcpJHDJAHD
kjkjn  NHYtcpHHGJJH
$ cat spw638403.addr
Address1=
Address2=
Address3=
$

[download]

running this code (note the -i.bak flag

#!/usr/bin/perl -i.bak
#
use strict;
use warnings;

my @list = ();

BEGIN
{
    my $inFile = q{spw638403.txt};
    open my $inFH, q{<}, $inFile
       or die qq{open: $inFile: $!\n};

    while ( <$inFH> )
    {
        chomp;
        push @list, ( split m{tcp}, ( split )[1] )[0];
    }

    close $inFH
       or die qq{close: $inFile: $!\n};
}

while ( <> )
{
    s{$}{$list[$. - 1]};
    print;
}

[download]

with the address file as the argument results in the original file preserved as spw638403.addr.bak and the modified file as spw638403.addr

$ ./spw638403 spw638403.addr
$ cat spw638403.addr
Address1=XYZ
Address2=JKHKJH
Address3=NHY
$

[download]

I hope this is of use.

Cheers,

JohnGG

Update: Clarified point that the scripts needs the name of the file to be modified as an argument.

Update 2: Corrected senior moment with flag. It is, of course, the -i flag, not -p

In reply to Re: Need a little help appending lines by johngg
in thread Need a little help appending lines by perl4ever

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.