If you extract your data into a HoHoA keyed by 'hi'/'bye' then 'to'/'from' with the array elements being the values, you can then use min and max from List::Util to get what you want.

use strict;
use warnings;

use Data::Dumper;
use List::Util qw{ min max };

open my $textFH, q{<}, \ <<'END_OF_FILE' or die qq{open: $!\n};
hi:  65 abcdefghijklmnopqrst 85
bye: 12 bcdefghijklmnopqrstu 32

hi:  86 sagfsdgsgwsehbbdgops 106
bye: 33 afasdfdfafasaafadfad 53

END_OF_FILE

my %dataItems = ();

while ( <$textFH> )
{
    next unless m{^(hi|bye):\s+(\d+)\D+(\d+)};
    push @{ $dataItems{ $1 }->{ from } }, $2;
    push @{ $dataItems{ $1 }->{ to } }, $3;
}

close $textFH or die qq{close: $!\n};

print Data::Dumper->Dumpxs( [ \ %dataItems], [ q{*dataItems} ] );

my $hiFrom  = min( @{ $dataItems{ hi }->{ from } } );
my $hiTo    = max( @{ $dataItems{ hi }->{ to } } );
my $byeFrom = min( @{ $dataItems{ bye }->{ from } } );
my $byeTo   = max( @{ $dataItems{ bye }->{ to } } );

print
   qq{\$hiFrom = $hiFrom and \$hiTo = $hiTo\n},
   qq{\$byeFrom = $byeFrom and \$byeTo = $byeTo\n};

[download]

Here's the output (with Data::Dumper output included so you can see the data structure)

%dataItems = (
               'hi' => {
                         'to' => [
                                   '85',
                                   '106'
                                 ],
                         'from' => [
                                     '65',
                                     '86'
                                   ]
                       },
               'bye' => {
                          'to' => [
                                    '32',
                                    '53'
                                  ],
                          'from' => [
                                      '12',
                                      '33'
                                    ]
                        }
             );
$hiFrom = 65 and $hiTo = 106
$byeFrom = 12 and $byeTo = 53

[download]

I hope this is useful.

Cheers,

JohnGG

In reply to Re: extracting from text by johngg
in thread extracting from text by heidi

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.