Ah, you're right. I was thinking of the wrong exception and wrote the wrong test. 

use Test::More 'tests' => 5;

sub is_code {
    no warnings qw( void uninitialized );
    return eval { defined &{$_[0]} };
}

sub real_sub { die 'real sub called' }
my $sub_ref = sub { die 'sub ref called' };
my $undef;

ok( is_code( \&real_sub ), 'real sub ref is code' );
ok( is_code( $sub_ref   ), 'lexical sub ref is code' );
ok( ! is_code( $undef   ), 'undef is not code' );
ok( ! is_code( 'string' ), 'string is not code' );
ok( is_code( 'real_sub' ), 'string is code' );

[download]

So you still need an extra check in is_code. 

sub is_code {
    no warnings qw( void uninitialized );
    return '' ne ref $_[0] && eval { defined &{$_[0]} };
}

[download]

That's fairly simple, but I think I still prefer the battery of ref, Scalar::Util::reftype, Scalar::Util::blessed and overload::Method. 

use strict;
use warnings;

use Test::More 'tests' => 16;
use Scalar::Util qw( blessed reftype );

my $side_effect = 0;

package OverloadCode;
use overload '&{}' => sub { $side_effect = 1; sub {} };

package main;

sub is_code_eval {
    no warnings qw( void uninitialized );
    return '' ne ref $_[0] && eval { defined &{$_[0]} };
}
sub is_code_util {
    my $suspected_code = shift;

    return 0 if '' eq ref $suspected_code;
    return 1 if 'CODE' eq reftype $suspected_code;
    if (    blessed $suspected_code
         && overload::Method( $suspected_code, '&{}' ) ) {
        return 1;
    }
    return 0;
}

sub real_sub { $side_effect = 1 }

check_method( \&is_code_util, 'utils' );
check_method( \&is_code_eval, 'eval' );

sub check_method {
    my ( $tester, $name ) = @_;

    $side_effect = 0;
    my $sub_ref = sub { $side_effect = 1 };
    my $overcode = bless {}, 'OverloadCode';
    my $undef;

    ok( $tester->( \&real_sub ),   "$name: real sub ref is code" );
    ok( $tester->( $sub_ref   ),   "$name: lexical sub ref is code" );
    ok( ! $tester->( $undef   ),   "$name: undef is code" );
    ok( ! $tester->( 'string' ),   "$name: string is not code" );
    ok( ! $tester->( 'real_sub' ), "$name: real_sub as string is not c
+ode" );
    ok( $tester->( $overcode ),    "$name: overloaded reference is cod
+e" );
    # this test fails for the eval method
    ok( ! $side_effect,            "$name: no side effect" );
    is( $undef, undef,             "$name: \$undef is still undef" );
}

[download]

In reply to Re^4: Reference assessment techniques and how they fail by kyle
in thread Reference assessment techniques and how they fail by kyle

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.