Assuming you want to keep the dates in MM/DD/YY format, you could use a sort of Schwartzian Transform to do the sorting. The original date string is carried through the process unchanged and pulled out at the end (in the top map) and the month day and year are separated out so they are available to sort in the first (bottom-most) map. The middle map transforms the year so that (arbitrarily) any year >= 30 belongs to the 20th century and the rest belong to the 21st.

use strict;
use warnings;

my $cutoff = 30;

print
   map  { $_->[0] }
   sort {
            $a->[3] cmp $b->[3]
            ||
            $a->[1] cmp $b->[1]
            ||
            $a->[2] cmp $b->[2]
        }
   map  { $_->[3] += $_->[3] >= $cutoff ? 1900 : 2000; $_ }
   map  { [ $_, m{(\d\d)/(\d\d)/(\d\d)} ] }
   <DATA>;


__END__
12/24/99
09/06/04
12/03/99
06/24/99
10/17/98
04/24/99

[download]

The output.

10/17/98
04/24/99
06/24/99
12/03/99
12/24/99
09/06/04

[download]

I hope this is of interest.

Cheers,

JohnGG

In reply to Re: Combining s/// by johngg
in thread Combining s/// by kangaroobin

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.