Now a regex variant;) I don't know if you'd want to use it but it does demonstrate building a regex at run time.

while ( my $line = <DATA> ) {
    my ($new, $old) = split /\s+/, $line;
    my $rx = regex($new);
    print "$new can ", ( $old =~ /$rx/? '': 'NOT ' ), "be made from $o
+ld\n";
}

sub regex {
    my %letters;
    $letters{$_}++ for split //, lc shift;
    my $regex = join '', map { "(?=(?:.*${_}){$letters{$_}})" } keys %
+letters;
    return qr/\A$regex/si;
}

__DATA__
dog good
food fodder
lot total
fuse useful
poor porridge
root rotor
__END__
dog can be made from good
food can NOT be made from fodder
lot can be made from total
fuse can be made from useful
poor can NOT be made from porridge
root can be made from rotor
[download]

I'll show the regular expression generated from 'root' in detail

my $regex = qr{
\A                  # anchor at start for efficiency
  (?=               # positive lookahead for
    (?:
      .*            # anything
      r             # with an 'r' after it
    ){1}            # at least once
  )
  (?=               # positive lookahead for
    (?:.*t){1}      # a 't'
  )
  (?=               # positive lookahead for
    (?:.*o){2}      # for two 'o's
  )
}six;               # ignore case
[download]

All the lookaheads have to succeed for the regex to match.

On a side note I benchmarked the variants (?:.*r), (?:[^r]*+r) and (?:[^r*]r) on different input strings and found the first was usually fastest.

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.