I tend to go for ultra portability..

I've already said it doesn't help portability.
On unix, the end of line is \n
On Windows, the end of line is \n
On old Macs, the end of line is \n
On new Macs, the end of line is \n

qr/(?:\r\n|\n\r|\n|\r)/s will likely handle any end-of-line scenario in the modern world.

I didn't deny that. I said it should be centralized. Compare

my $re_single = qr/
    (?:\A|[\r\n]) # either the start of text or newline
    (
        [^\r\n]* # any non-newlines
        (?:\z|(?:\r\n|\n\r|\r|\n)\z) # last newline or eof
    )
/xs;

my $re_multiple = qr/
    (?:\A|[\r\n]) # either the start of text or newline
    (
        (?:
            [^\r\n]*
            (?:\r\n|\n\r|\r|\n)
        ){0,$nless}
    ) # have to enclose above so it all goes into $1
    (
        [^\r\n]*
        (?:\z|(?:\r\n|\n\r|\r|\n)\z) # last nl or eof
    )
/xs;
[download]

to

my $re_single = qr/
   ^ ( .* \n? \z )
/mx;

my $re_multiple = qr/
    ^
    ( (?: .* \n ){0,$nless} )
    ( .* \n? \z )
/mx;

$String =~ s/\r\n|\n\r|\r|\n/\n/g;
[download]

In short, it's not Last_N_Lines's job to decode IO.

---

By the way, there are more improvements you can make.

• $re_single is just a special case of $re_multiple. You can use $re_multiple even when only one line is needed.
• You don't need two captures. Combine them into one.
• This is the perfect place for the ternary operator.

Compare

my $re_single = qr/
    (?:\A|[\r\n]) # either the start of text or newline
    (
        [^\r\n]* # any non-newlines
        (?:\z|(?:\r\n|\n\r|\r|\n)\z) # last newline or eof
    )
/xs;

sub Last_N_Lines {
    my ( $str, $n ) = @_;

    my $nless = ( $n - 1 );

    my $re_multiple = qr/
        (?:\A|[\r\n]) # either the start of text or newline
        (
            (?:
                [^\r\n]*
                (?:\r\n|\n\r|\r|\n)
            ){0,$nless}
        ) # have to enclose above so it all goes into $1
        (
            [^\r\n]*
            (?:\z|(?:\r\n|\n\r|\r|\n)\z) # last nl or eof
        )
    /xs;

    if ( $n > 1 ) {
        if ( $str =~ m/$re_multiple/ ) {
            return( "$1$2" );
        } else {
            return( "" );
        }
    }

    if ( $str =~ m/$re_single/ ) {
        return( $1 );
    } else {
        return( "" );
    }
}
[download]

to

sub Last_N_Lines {
    my ( $str, $n ) = @_;

    my $nless = ( $n - 1 );

    return $str =~ /
        ^
        (
           (?: .* \n ){0,$nless}
           .* \n?
        )
        \z
    /mx ? $1 : "";
}

$String =~ s/\r\n|\n\r|\r|\n/\n/g;
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.