This looks pretty slick.

I'd probably put some more abstraction into the interface of the loader function. Also, you shouldn't need two steps to create a backup and install a new sub. 

#!/usr/bin/perl

package test_package;

use strict;
use warnings;

sub new { return bless {}; }

sub test_function { print "Original test_function! $_[1]\n"; }

sub loader {
    my $self         = shift;
    my $override     = shift; # Name of function to override.
    my $new_function = shift; # code ref to install

    my $backup; # keep a code ref of the original here.

    local @_;
    eval {
        no strict 'refs';
        no warnings 'redefine';

        die "Can't override non-existant function $override\n"
            unless exists &{$override};
        
        $backup = \&{$override};
        *{$override} = $new_function;
    };
    
    if ( $@ ) {
        warn "ERROR: $@\n" if ( $@ );
        $backup = undef;
    }

    return $backup;
}

package main;

use strict;
use warnings;

my $counter = 0;

my $f = new test_package();

$f->test_function($counter++); # 1

my $newsub =  sub { print "New output! $_[1]+\n"; 1 };

# Replace function, get backup in return.
my $backup = $f->loader( 'test_package::test_function', $newsub );

$f->test_function($counter++);

# Restore function.
$f->loader( "test_package::test_function", $backup);
$f->test_function($counter++);

my $faked =$f->loader( "test_package::fake_function", $newsub );
warn "Unable to override function" unless $faked;


#$f->fake_function( 'Fake');  # program will die

[download]

If you specifically want to focus on overriding and restoring functions, you could actually use your object to store the names of overridden functions and their original code refs. Then your code could look like this: 

$f->override( 'test::function', sub { print 'foo' } );
# Do your testing;
$f->restore( 'test::function' );

[download]

Update: You might also want to look at Sub::Installer.


TGI says moo

In reply to Re: "Backing up" a subroutine during runtime. by TGI
in thread "Backing up" a subroutine during runtime. by dextius

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.