Here is a slightly simpler iterator than jethro's, but surely it's doing the same thing. It avoids the recursion blowup of JavaFan. 
sub iterator {
  return unless @_;

  my @p = ($_[0]);
  return sub {

    ## collect all the trailing 2s, and last trailing 3 if present
    my $temp = 0;
    $temp += pop @p while @p and $p[-1] == 2;
    $temp += pop @p if    @p and $p[-1] == 3;    ## updated
    return if ! @p;

    ## reduce the last guy by 1, avoid total of 1 leftover
    $p[-1]--, $temp++;
    $p[-1]--, $temp++  if $temp == 1;

    ## redistribute collected amount, as large as possible
    ## (largest increments can be $p[-1])
    if ($temp % $p[-1] == 0) {
        push @p, ($p[-1]) x ($temp/$p[-1]);

    ## special case to avoid 1 leftover
    } elsif ( $temp % $p[-1] == 1 ) {
        my $m = int ($temp/$p[-1]) -1;
        push @p, ($p[-1]) x $m, $p[-1]-1, 2;

    } else {
        my $m = int ($temp/$p[-1]) ;
        push @p, ($p[-1]) x $m, ($temp - $p[-1]*$m);
    }

    @p;
  }
}

my $iter = iterator(shift || 50);

while (my @part = $iter->()) {
    print "@part\n";
}

[download]
Like jethro's, there could be some efficiencies gained by keeping track of some pointers, but the main problem is that there are just so many partitions. So I think the problem statement should be clarified, especially if 10^6 is involved.

Update: updated the marked line according to BrowserUk's suggestion. (added "@p and").

blokhead

In reply to Re: Decomposing sum to unique sets of summands by blokhead
in thread Decomposing sum to unique sets of summands by blackmanao

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.