Hi, I'm guessing the reason your separate thread didn't work may be the way you setup your shared hash. What you want to do, for maximum speed, is have your worker thread load the files from disk, make the pixbuf, and thumbnail, then stuff them into a hash. This may make a huge hash if you have many images.

IIRC, that was the reason I didn't have a worker thread do all the pixbufs, .... the hash could get huge, so it was better to only add images after you selected a dir to browse. Someone asked this question before, (maybe you?), and the best solution, if you have a static set of images, is to make a pre-processor script that goes through all the images first, makes the thumbnails, then stores the thumbs in a Storable db which you open at the program start. This will load all the thumbnails very fast, and you can then load the full image as needed.

Here is the basic idea. Put your images in a 'pics' subdir, and run this script. The first run will be slow, but the second run will be fast, as it loads from a single db. 

#!/usr/bin/perl 
use warnings;
use strict;
use Tk;
use Tk::Pane;
use Tk::JPEG;
use MIME::Base64;
use Imager;
use File::Basename;
use File::Path;
use File::Copy;
use Storable;
use POSIX qw(strftime);
use YAML;

my $photo;#my $photo;
my $image;
my %info;
my @exts = qw(.jpg .png .gif); # list allowed extensions

if(-e 'notebook.db'){
     %info = %{retrieve('notebook.db')};   # direct to hash 
    }else{ make_thumbs() } 

#to see a dump of the db, just put an 1 as an arg to the script
if(shift){print Dump(\%info);exit;}

my $mw = MainWindow->new(-bg=>'black');
$mw->geometry('800x700+100+15');

#setup auto save of storable db
$mw->protocol('WM_DELETE_WINDOW' => sub { &save_it() });
$SIG{__DIE__} = sub { &save_it()};
$SIG{INT} = sub { &save_it()};
$mw->bind('<Control-c>', [sub{&save_it(); Tk::exit;}] );

my $mainframe = $mw->Frame(-background=>'black')
                            ->pack(-side => "right", -anchor => "n",
                             -fill=>'both', -expand=>1);

#fill mainframe with default screen 
setup_pane();

MainLoop;

################################################
sub setup_pane{

my $pane = $mainframe->Scrolled('Pane', Name => 'Main Display',
               -width => 1000,
           -height =>1000,
               -background => 'black',
           -scrollbars => 'osoe',
               -sticky => 'n',
              )->pack(-side => "left", -anchor => "n",
                  -fill=>'both',-expand=>1);

foreach my $key ( keys %info ){
            my $image = $mw->Photo(
             -data => $info{$key}{'thumbnail'} );

            $pane->Label(-image => $image, 
               -background =>'black'
                 )->pack(-side => 'top',
                  -anchor => 'n',
                  -fill => 'both',
          -expand => 1,
         );
      }
}
###############################################
sub make_thumbs{

umask 0022;

my @pics = <pics/*.jpg pics/*.gif pic/*.png>;
my $image = Imager->new();

foreach my $pic (@pics){    
            my ($basename,$path,$suffix) = fileparse($pic,@exts);
                    
            $info{$basename}{'name'} = $basename;
        $info{$basename}{'pic'} = "pics/$basename.jpg"; #convert to jp
+g
            $image->open(file=>$pic) or die $image->errstr();

        # Create smaller version
         my $temp;
         my $thumb = $image->scale(xpixels=>100);
         print "Storing thumbnail: $basename.jpg\n";

         $thumb->write(data => \$temp, 
                   type =>'jpeg',
                       jpegquality=>30) or die $thumb->errstr;
         
     $info{$basename}{'thumbnail'} = encode_base64($temp);
    }

print "\n#########endofthumbcreation#####################\n";

}
###############################################
sub save_it{
store(\%info,'notebook.db');
print "saved\n";
exit;
}
#################################################

[download]
I'm not really a human, but I play one on earth Remember How Lucky You Are

In reply to Re^2: Gtk2-thumbnail-previewer by zentara
in thread Gtk2-thumbnail-previewer by zentara

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.