map says that both EXPR and BLOCK are evaluated in list context. Using a parenthetical list is ambiguous as they are taken as enclosing the arguments to map I think.

$ perl -le '
> %h = map ( $_, 2 * $_ ), 1 .. 3;
> print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
0 - 
$

[download]

Using an anonymous array emits a single scalar containing the reference so you then need another map to dereference it.

$ perl -le '
%h = map @$_, map [ $_, 2 * $_ ], 1 .. 3;
print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
1 - 2
2 - 4
3 - 6
$

[download]

You could construct a subroutine that returns a list in the fly.

$ perl -le '
%h = map sub { return ( $_, 2 * $_ ) }->( $_ ), 1 .. 3;
print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
1 - 2
2 - 4
3 - 6
$

[download]

Simplest is to use map BLOCK list as already suggested.

$ perl -le '
%h = map { $_, 2 * $_ } 1 .. 3;
print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
1 - 2
2 - 4
3 - 6
$

[download]

I hope this is of interest.

Cheers,

JohnGG

Update: Couldn't see the wood for the parentheses, just add an extra pair so there's no ambiguity.

$ perl -le '
%h = map ( ( $_, 2 * $_ ), 1 .. 3 );
print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
1 - 2
2 - 4
3 - 6
$

[download]

Update 2: Another way is to use a do block.

$ perl -le '
> %h = map do { ( $_, 2 * $_ ) }, 1 .. 3;
> print qq{$_ - $h{$_}} for sort {$a <=> $b} keys %h;'
1 - 2
2 - 4
3 - 6
$

[download]

In reply to Re: map EXPR - what's an EXPR? by johngg
in thread map EXPR - what's an EXPR? by missingthepoint

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.