Original code more sanely formatted:

if (scalar @row1 == "6") {
   @entry1 = (@required , @row1);
   $digest1 = sha1_hex(@entry1);
   $sth = $dbh->prepare($query);
   $sth->execute($digest1);
   $data1 = $sth->fetchrow_array();
   if ($data1 ne $digest1) {
      push(@entry1, $digest1);
      $sth = $dbh->prepare($insert);
      $sth->execute(@entry1);
      &create_pdf(@entry1);
      $msg->attach(
         Type        => 'image/gif',
         Path        => "../pdfs/ir_$digest1.pdf",
         Filename    => "ir_$digest1.pdf",
         Disposition => 'attachment'
      )
   } else {
      $dberror .= "The following row you submitted: "
               .  "<br> @entry1 "
               .  "<br>already exsits in the database "
               .  "and will note be re-submitted. <br>"
   }
};
[download]

Let's start by identifying bugs.

• What fetchrow_array returns in scalar context is undocumented.
  $data1 = $sth->fetchrow_array();
  is wrong. If you want to the first field, use
  ($data1) = $sth->fetchrow_array();

• Is the contents of $dberror text of HTML? You put both into it. At worst, this could be an opening for a cross-site scripting attack.

• All over, you are instructing Perl to ignore prototypes. Why do you use & on your subroutine calls?

• I note a distinct lack of my. Use use strict;!

• Something tells me you don't use warnings either. ("if ($data1 ne $digest1)" would warn if fetchrow_array returned zero rows.) Use use warnings;!

• Why is six in quotes in "if (scalar @row1 == "6")"? You want to compare with the number 6, not the string "6" (which would be converted to a number by ==). The scalar is useless too. == creates a scalar context, so scalar is redundant.

As for your actual question, replace

if (@row1 == 6) {
   my @entry1 = (@required , @row1);
   ...
}
[download]

with

for my $row ( 1 .. $#rows ) {
   if (@{$rows[$row]} == 6) {
      my @entry = (@required , @{$rows[$row]});
      ...
   }
}
[download]

and remove all other mentions of "1".

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.