Better structured XML would help! However you can do what you want by using what is effectively a state machine and deferring output until you can make the decision. Consider:

use strict;
use warnings;
use XML::Parser;

my $xmlStr = <<'END_XML';
<doc>
<customBucket></customBucket>
<customDimensionName>Strategy</customDimensionName>
<customBucketValueString>Test1</customBucketValueString>
<customBucketEnd></customBucketEnd>
<customBucket></customBucket>
<customDimensionName>SubStrategy</customDimensionName>
<customBucketValueString>Test2</customBucketValueString>
<customBucketEnd></customBucketEnd>
</doc>
END_XML
my %state = (printing => 1);
my $parser = XML::Parser->new (Style => 'Stream', Pkg => '::main');

$parser->parse ($xmlStr);


sub StartTag {
    my ($p, $elt) = @_;
    my $eltStr = $_;

    if ($elt eq 'customBucket') {
        $state{printing} = undef;

    } elsif ($elt eq 'customDimensionName') {
        $state{capturing} = 1;
        $state{capture} = '';
    }

    if ($state{printing}) {
        print $eltStr;

    } else {
        $state{text} .= $eltStr;
    }
}


sub Text {
    my ($p) = @_;
    my $str = $_;

    if ($state{printing}) {
        print $str;
    } else {
        $state{text} .= $str;
        $state{capture} .= $str if $state{capturing};
    }
}


sub EndTag {
    my ($p, $elt) = @_;
    my $eltStr = $_;

    if ($state{printing}) {
        print $eltStr;
    } else {
        $state{text} .= $eltStr;
    }

    if ($elt eq 'customBucketEnd') {
        if ($state{capture} !~ '^Strategy$') {
            print "$state{text}";
        }

        $state{text} = '';
        $state{capture} = '';
        $state{printing} = 1;
    } elsif ($elt eq 'customDimensionName') {
        $state{capturing} = undef;
    }
}

[download]

Prints:

<doc>

<customBucket></customBucket>
<customDimensionName>SubStrategy</customDimensionName>
<customBucketValueString>Test2</customBucketValueString>
<customBucketEnd></customBucketEnd>
</doc>

[download]
True laziness is hard work

In reply to Re: How to exclude certain blocks of an XML file using Perl and XML::Parser by GrandFather
in thread How to exclude certain blocks of an XML file using Perl and XML::Parser by kgullekson

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.