#! /usr/bin/perl

use strict;
use warnings;
use HTML::TreeBuilder;

use Data::Dumper;
$Data::Dumper::Indent = 2;

my $html = do{local $/;<DATA>};
my $t = HTML::TreeBuilder->new_from_content($html) 
  or die qq{cant parse html: $!\n};

# get a list of p tags
my @paras = $t->look_down(_tag => q{p});

my @blocks;
for my $para (@paras){
  
  my $txt;
  # skip any of the tags at the start of the p tag,
  # collect the first text found
  # stop if a br tag found
  for my $item ($para->content_refs_list){
    if (ref $$item){
      # we have a tag
      my $tag = $$item->tag;
      last if $tag eq q{br};
      next;
    }
    # we have text
    $txt = $$item;
  }
  
  # is it the p tag we need?
  my ($title, $words);
  next unless ($title, $words) = $txt =~ /\s---\s(.*?)\s---\s(.*)/;
  
  # look down the p tag for the object
  my $object = $para->look_down(_tag => q{object})
    or die qq{look down didnt find object};
  
  # stuff what we've found into a table
  push @blocks, {
    title => $title,
    words => $words,
    object => $object->as_HTML(undef, q{ }, {}),
  }
  
}

print Dumper \@blocks;

__DATA__
<html><head><title>six blocks</title></head><body>

<p>text we don&lsquo;t want</p>
<p>text we don&lsquo;t want</p>

<p id="block1"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE1 --- WORDS1 WORDS1 WORDS1 WORDS1 WORDS1 WORDS1<BR>
<object id="object1"><param>If you can read this you are too close.</o
+bject>
</p>

<p id="block2"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE2 --- WORDS2 WORDS2 WORDS2 WORDS2 WORDS2 WORDS2<BR>
<object id="object2"><param>If you can read this you are too close.</o
+bject>
</p>

<p id="block3"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE3 --- WORDS3 WORDS3 WORDS3 WORDS3 WORDS3 WORDS3<BR>
<object id="object3"><param>If you can read this you are too close.</o
+bject>
</p>

<p>text we don&lsquo;t want</p>

<p id="block4"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE4 --- WORDS4 WORDS4 WORDS4 WORDS4 WORDS4 WORDS4<BR>
<object id="object4"><param>If you can read this you are too close.</o
+bject>
</p>

<p id="block5"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE5 --- WORDS5 WORDS5 WORDS5 WORDS5 WORDS5 WORDS5<BR>
<object id="object5"><param>If you can read this you are too close.</o
+bject>
</p>

<p id="block6"><img src="pic.jpg"><a href="link.html">link</a> --- TIT
+LE6 --- WORDS6 WORDS6 WORDS6 WORDS6 WORDS6 WORDS6<BR>
<object id="object6"><param>If you can read this you are too close.</o
+bject>
</p>

<p>text we don&lsquo;t want</p>
<p>text we don&lsquo;t want</p>

</body></html>

[download]
$VAR1 = [
          {
            'object' => '<object id="object1">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE1',
            'words' => 'WORDS1 WORDS1 WORDS1 WORDS1 WORDS1 WORDS1'
          },
          {
            'object' => '<object id="object2">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE2',
            'words' => 'WORDS2 WORDS2 WORDS2 WORDS2 WORDS2 WORDS2'
          },
          {
            'object' => '<object id="object3">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE3',
            'words' => 'WORDS3 WORDS3 WORDS3 WORDS3 WORDS3 WORDS3'
          },
          {
            'object' => '<object id="object4">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE4',
            'words' => 'WORDS4 WORDS4 WORDS4 WORDS4 WORDS4 WORDS4'
          },
          {
            'object' => '<object id="object5">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE5',
            'words' => 'WORDS5 WORDS5 WORDS5 WORDS5 WORDS5 WORDS5'
          },
          {
            'object' => '<object id="object6">
 <param />If you can read this you are too close.</object>
',
            'title' => 'TITLE6',
            'words' => 'WORDS6 WORDS6 WORDS6 WORDS6 WORDS6 WORDS6'
          }
        ];

[download]
btw <object.*> is greedy but that is only the start of your problems. :-)

update: tweaked the html
update2: removed module that isn't used

In reply to Re: Trying to parse html file by wfsp
in thread Trying to parse html file by annunaki10

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.