If you're ok with changing 

return unless ref($hashref) eq 'HASH';

[download]

to 

return unless keys %$hashref;

[download]

then you can use the following: 

sub treeify {
    my ($sth) = @_;

    my %root;
    my %children;

    while (my $row = $sth->fetch()) {
        my ($id, $parent_id) = @$row;

        my $parent = ( defined($parent_id)
            ? $children{$parent_id} ||= {}
            : \%root
        );

        $parent->{$id} = $children{$id} ||= {};
    }

    return \%root;
}

[download]

Test: 

{
    my $sponge = DBI->connect(
        'dbi:Sponge:', '', '',
        { RaiseError => 1 }
    );

    my $sth = $sponge->prepare(
        'SELECT id, parent_id FROM Table',
        {
            NAME => [qw( id parent_id )],
            rows => [
                [ a => undef ],
                [ b => 'a'   ],
                [ d => 'c'   ],
                [ c => 'b'   ],
                [ e => 'a'   ],
            ],
        }
    );

    my $tree = treeify($sth);

    use Data::Dumper;
    print Dumper $tree;
}

[download]

Output: 

$VAR1 = {
          'a' => {
                   'e' => {},
                   'b' => {
                            'c' => {
                                     'd' => {}
                                   }
                          }
                 }
        };

[download]

In reply to Re: Generating a Hash of Hashes Recursively to Display Database Hierarchy by ikegami
in thread Generating a Hash of Hashes Recursively to Display Database Hierarchy by c4onastick

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.