The symbol = is compiled into one of two assignment operators:

• A list assignment operator is used if the left-hand side (LHS) of a = is some kind of aggregate.
• A scalar assignment operator is used otherwise.

The following are considered to be aggregates:

• Any expression in parentheses (e.g. (...))
• An array (e.g. @array)
• An array slice (e.g. @array[...])
• A hash (e.g. %hash)
• A hash slice (e.g. @hash{...})
• Any of the above preceded by my, our or local

There are two differences between the operators.

Context of Operands

The two operators differ in the context in which their operands are evaluated.

• The scalar assignment evaluates both of its operands in scalar context.
• The list assignment evaluates both of its operands in list context.

Value(s) Returned

The two operators differ in what they return.

Note that the right-hand side is used for the list assignment in scalar context.

Examples

# @array evaluated in scalar context.
my $count = @array;
[download]

# The s/// operates on $copy.
(my $copy = $str) =~ s/\\/\\\\/g;
[download]

# Prints $x.
print($x = $y);
[download]

# @array evaluated in list context.
my @copy = @array;
[download]

# @array evaluated in list context.
my ($first) = @array;
[download]

# Only dies if f() returns an empty list.
# This does not die if f() returns a
# false scalar like zero or undef.
my ($x) = f() or die;
[download]

my $count = () = f();
[download]

# Prints @x.
print(@x = @y);
[download]

Related topics:

• Perl Idioms Explained - my $count = () = /.../g.

Update: Added examples.
Update: Incorporated JavaFan's additions.
Update: Removed list slices and mentioned state.
Update: One of the examples in the scalar context column did not depend on context. It has been moved to its own column. Also, added short explanations of examples.
Update: Reworded to not say there are only two assignment operators, because += and such are also assignment operators.
Update: Reworded to include new fangled []->@* to the list of aggregates.