The lines that have 'hardware ethernet' on them are causing my big script to misinterpret the information.

A more elegant solution might be to fix the "big script" not to care about the order the lines come in. Here is one example that parses the config file and returns hash references of all the data.

#!/usr/bin/perl

use warnings;
use strict;

sub parse_host_cfg
{
    my ($file) = @_;

    my %fields;

    HOST_CFG_LOOP:
    while ( my $line = <$file> ) {
        chomp $line;
        last HOST_CFG_LOOP if ( $line =~ /\A\s*}/ );

        if ( my ($name, $value) = $line =~ /^([-\w\s]+) "?(.*?)"?;/ ) 
+{
            $fields{$name} = $value;
        }
        else {
            warn "invalid host config line: $line";
        }
    }

    return \%fields;
}

sub parse_cfg_file
{
    my %hosts;
    my ($file) = @_;

    while ( my $line = <$file> ) {
        chomp $line;
        if ( my ($hostid) = $line =~ /^host\s+(\w+)\s+{/ ) {
            my $host_cfg = parse_host_cfg( $file );
            $hosts{$hostid} = $host_cfg;
        }
    }

    return \%hosts;
}

use Data::Dumper;
print Dumper parse_cfg_file( *DATA );

__DATA__
# Host 1
host 45583 {
filename "junk1.cm";
hardware ethernet 11:42:a3:d4:55:83;
fixed-address 10.100.34.114;
}
# Host 2
host D78C3 {
filename "junk5.cm";
fixed-address 10.100.34.117;
hardware ethernet 11:42:a3:FD:78:C3;
aklsjdhflkajsdfhlkjh
}
}
# Host 3
host 3A684 {
filename "junk6.cm";
fixed-address 10.100.34.119;
hardware ethernet 11:42:a3:13:a6:84;
}
# Host 4
host 46d54 {
filename "junk4.cm";
fixed-address 10.100.34.120;
hardware ethernet 23:10:3d:14:6d:54;
}

[download]

In reply to Re: swapping lines that match a condition by juster
in thread swapping lines that match a condition by TheBigAmbulance

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.