ikegami will probably come along and embarrass me by doing this in 4 lines but here you go. You can easily skip the DN elements if you choose or do a separate XML doc for each, et cetera, with what I hope will become obvious tweaking. XML with regexes is a land of tears. Just say no. Reading: XML::LibXML. Update: also, ->toFile in XML::LibXML::Document to easily put the DN ids out to files though the necessary tweaks to the code to create a doc per DN are left to you. :) 

use strict;
use warnings;
use XML::LibXML;

my $doc = XML::LibXML::Document->new( "1.0", "UTF-8" );
my $root = $doc->createElement("root");
$doc->setDocumentElement( $root );

while ( my $ident = <DATA> )
{
    $ident =~ s/\A\.\.|:.*//gs;
    chomp( my $value = <DATA> );
    my $node = $doc->createElement($ident);
    $node->addChild($doc->createTextNode($value));
    if ( $ident eq "p" )
    {
        my $last = $root->lastChild;
        if ( $last->nodeName eq "con" )
        {
            $last->addChild($node);
        }
        else
        {
            my $con = $doc->createElement("con");
            $root->addChild($con);
            $con->addChild($node)
        }
    }
    else
    {
        $root->addChild($node);
    }
}

print $doc->serialize(1);

__DATA__
..DN:
1
..id:
000044119
..DD:
Friday, October 30, 2009
..p:
THis is param1
..p:
THis is param2
..p:
THis is param3
..DN:
2
..id:
000044119
..DD:
Friday, October 30, 2009
..p:
THis is param1
..p:
THis is param2
..p:
THis is param3

[download]

Output-

<?xml version="1.0" encoding="UTF-8"?>
<root>
  <DN>1</DN>
  <id>000044119</id>
  <DD>Friday, October 30, 2009</DD>
  <con>
    <p>THis is param1</p>
    <p>THis is param2</p>
    <p>THis is param3</p>
  </con>
  <DN>2</DN>
  <id>000044119</id>
  <DD>Friday, October 30, 2009</DD>
  <con>
    <p>THis is param1</p>
    <p>THis is param2</p>
    <p>THis is param3</p>
  </con>
</root>

[download]

In reply to Re: replace the first tag by Your Mother
in thread replace the first tag by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.