Your code doesn't run at all in fact. @array does not exist and your prototyped sub is declared too late for the prototype to be checked.

As already suggested use strictures (use strict; use warnings; - see The strictures, according to Seuss).

Don't use prototyped subs. In your sample code the prototype says "take no parameters" but @array is almost certainly intended to be a parameter (you surely aren't using global variables are you?).

A first cut at cleaning up the code could look like:

#!/usr/bin/perl
use strict;
use warnings;

my @deck = qw(card1 card2 card3 card4);

my @shuffle1 = shuffle (@deck);
my @shuffle2 = shuffle (@shuffle1);

print "@shuffle1\n";
print "@shuffle2\n";

sub shuffle {
    my $first = 0;
    my $last = $#_;
    my @newdeck;

    while ($first < $last) {
        push @newdeck, $_[$last--], $_[$first++];
    }

    return @newdeck;
}

[download]

Using a somewhat more Perlish (and probably harder to understand) approach to implementing shuffle may get you to:

sub shuffle {
    my @newdeck;

    push @newdeck, @_[-$_ - 1, $_] for 0 .. @_ / 2 - 1;
    return @newdeck;
}

[download]

Both versions print:

card4 card1 card3 card2
card2 card4 card3 card1

[download]
True laziness is hard work

In reply to Re: When function is executed twice I get the results from the first set in the second by GrandFather
in thread When function is executed twice I get the results from the first set in the second by gstoykov

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.