Sounds like fun!:

# IHeartFortran.pm
package IHeartFortran;
use strict; use warnings;
require Exporter;
our @ISA = qw( Exporter );
our @EXPORT = qw/ EQV NEQV /;

use overload '.' => \&_do_op;

sub _do_op {
  my ($self, $y, $reverse) = @_;
  $$self{ $reverse ? 'left' : 'right' } = $y;
  if (exists($$self{left}) and exists($$self{right})) {
    return $$self{op}->(@$self{qw/ left right /});
  }
  return $self;
}


sub new {
  my ($class, $op) = @_;
  bless { op => $op }, $class;
}

sub EQV()  { __PACKAGE__->new( sub { $_[0] == $_[1] ? 1 : 0 } ) }
sub NEQV() { __PACKAGE__->new( sub { $_[0] != $_[1] ? 1 : 0 } ) }

[download]

Then to use it:

#!/usr/bin/perl
use strict; use warnings; use 5.010;
use IHeartFortran;

say 1 .EQV. 1;
say 1 .EQV. 2;

say 1 .NEQV. 1;
say 1 .NEQV. 2;

[download]

This doesn't exactly create a .EQV. operator (for instance, spaces would be allowed:  1 . EQV . 2), but it looks good enough.

update: Actually, I think FORTRAN's whitespace rules would allow extra spaces anyway, so perhaps this is a somewhat faithful recreation anyway. Case flexibility on the other hand...

Good Day,
    Dean

In reply to Re: Hints Towards Writing a Module with New Operators by duelafn
in thread Hints Towards Writing a Module with New Operators by swampyankee

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.