use threads;
use Socket     qw( AF_UNIX SOCK_STREAM PF_UNSPEC );
use IO::Handle qw( );

sub _pipe {
    socketpair($_[0], $_[1], AF_UNIX, SOCK_STREAM, PF_UNSPEC)
        or return undef;
    shutdown($_[0], 1);  # No more writing for reader
    shutdown($_[1], 0);  # No more reading for writer
    return 1;
}

sub sockify_stdin {
    open(my $real_stdin, '<&', *STDIN)
        or die("Can't dup STDIN: $^E\n");
    _pipe(*STDIN, my $stdin_w)
        or die("Can't create socketpair: $^E\n");
    $stdin_w->autoflush(1);

    async {
        close(STDIN); # Close this threads's copy.
        print $stdin_w $_ while <$real_stdin>;
        close($stdin_w);
    }->detach();

    close($stdin_w); # Close this threads's copy.
}

[download]
Sample usage: 
use IO::Select qw( );

sockify_stdin();

my $stdin_buf = '';

my $sel = IO::Select->new(*STDIN);
while (my (@ready) = $sel->can_read()) {
    my $rv = sysread(*STDIN, $stdin_buf, 64*1024, length($stdin_buf));
    die if !defined($rv);
    last if !$rv;
    while ($stdin_buf =~ s/(.*\n)//g) {
        print "$1";
    }
}

print "$stdin_buf\n" if length($stdin_buf);

[download]

In reply to Re^6: Multiplexing problem by ikegami
in thread Multiplexing problem by grlemn

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.