Fixed numerous bugs and issues: 

#!/usr/bin/env perl
use strict;
use warnings;

use IPC::System::Simple qw( systemx );

sub usage {
   print(STDERR "$_[0]\n") if @_;
   print(STDERR "usage: $0 user muser [ user muser [ ... ] ]\n");
   exit(1);
}

sub get_user_home {
   return (getpwnam($_[0]))[7];
}

usage("Wrong number of args\n")
   if @ARGV % 2 != 0;

my $success = 1;
while (@ARGV) {
   my $user  = pop;
   my $muser = pop;
   
   my $home = get_user_home($user);
   if (!defined($home)) {
      warn("No such user \"$user\"\n");
      $success = 0;
      next;
   }

   if (-d $home) {
      warn("User \"$user\" already has a home directory\n");
      $success = 0;
      next;
   }

   my $mhome = get_user_home($muser);
   if (!defined($mhome)) {
      warn("No such user \"$muser\"\n");
      $success = 0;
      next;
   }

   if (!eval {
      systemx(mkdir => ( $home ));
      systemx(chown => ( "$user:users", $home ));
      systemx(ln => ( '-s', "$mhome/.profile", "$home/.profile" ));
      1
   }) {
      warn($@);
      $success = 0;
      next;
   }
}

exit($success ? 0 : 1);

[download]

In reply to Re: switching from <> to $ARGV by ikegami
in thread switching from <> to $ARGV by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.