ikegami, I don't understand your solution.

Which part? I wrote it to be extremely straightforward. Each line is completely independent of the others.

There is no need to undef the scalars,

I think you mean there is no need to get rid of references to undef. If so, then just get rid of the following:

if ($reftype eq 'REF' || $reftype eq 'SCALAR') {
      clean($$node);
      $node = undef if !defined($$node);
   } els
[download]

(Like I said, very modular.)

sub clean {
   our $node; local *node = \$_[0];  # Alias
   return if !defined($node);

   my $reftype = ref($node);
   return if !$reftype;

   if ($reftype eq 'ARRAY') {
      clean($_) for @$node;
      @$node = grep defined, @$node;
      $node = undef if !@$node;
   } elsif ($reftype eq 'HASH') {
      clean($_) for values(%$node);
      delete @{$node}{ grep !defined($node->{$_}), keys(%$node) };
      $node = undef if !keys(%$node);
   }
}
[download]

it didn't delete the empty arrays

It both empties arrays (removes any undefs from them), and deletes references to empty arrays. I even showed that it does. Here's a couple more tests:

[[[],[],["b"]],"a"]
[[["b"]],"a"]

[[[],[],[]],"a"]
["a"]
[download]

Could you give a case that breaks?

            my $n = scalar(keys %$ref);
            if ($n == 0) {
                  return 0;
            }
            return 1;
[download]

I find it weird that clean() returns false when the node is clean (empty). Either way, your code could be simplified to

return keys(%$ref) ? 1 : 0;
[download]

or even just

return keys(%$ref);
[download]