class_vars was being called too late to be of any use.

Putting a BEGIN block around a sub definition is useless, as a sub definition doesn't generate code to execute.

Contrary to what you said, you weren't getting a syntax error, you were getting a strict error. Quite appropriate since you asked for it.

Solution: 

BEGIN {
   package class_vars;

   use strict;
   use warnings;

   sub import {
      shift;
      my $pkg = caller;
      for my $var (@_) {
         eval("
            package $pkg;
            use vars '\$$var';
            sub $var {
               \$$var = \$_[1] if \@_ > 1;
               return \$$var;
            }
         ");
      }
   }

   $INC{'class_vars.pm'} = __FILE__;
}


{
   package MyPackage;

   use strict;
   use warnings;

   use class_vars qw( one two three );

   sub init_one_from_three {
      $one=$three-2;
   }

   sub new {
      my $package=shift;
      my $parms=$_[0];
      
      my $this={};

      foreach(keys %$parms) {
         no strict 'refs';
         $$_=$parms->{$_};
      }

      bless $this, $package;
   }
}


{
   use strict;
   use warnings;

   my $p=new MyPackage({three => 3,});

   $p->two(2);
   $p->init_one_from_three;

   printf "one=%d two=%d, three=%d\n", $p->one, $p->two, $p->three;
}

[download]
one=1 two=2, three=3

[download]
The following simulates putting the module in its own file: 
BEGIN {
   ...
   $INC{'class_vars.pm'} = __FILE__;
}

[download]

Package declarations are lexically scoped. You had lots of needless package switching.

I left in the limit that class vars must be scalars.

You call them class vars, but then you initialise them when constructing an instance, and you access them via a class instance. They're not class variables at all. They're object attributes, and you're going the wrong way about creating a singleton.

Update: Adjust the value in %INC as per reply.

In reply to Re: More Macro work...out to export a definition to next-outer level? by ikegami
in thread More Macro work...out to export a definition to next-outer level? by perl-diddler

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.