One approach is to use Twig handlers. For example: 
use warnings;
use strict;
use XML::Twig;

my $xmlstr = <<EOF;
<AGENT hostname="viper3">
 <LADDER>
  <ACL>
   <ACCOUNT id="4cf031986c">
    <USERNAME>emcon</USERNAME>
    <HOST>*sppcon*</HOST>
    <PERMISSION>CDOPS</PERMISSION>
   </ACCOUNT>
   <ACCOUNT id="b92794bbd7">
    <USERNAME>cpemcon</USERNAME>
    <HOST>*</HOST>
    <PERMISSION>COPS</PERMISSION>
   </ACCOUNT>
   <ACCOUNT id="8ff0478641">
    <USERNAME>dbemcon</USERNAME>
    <HOST>*</HOST>
    <PERMISSION>COPS</PERMISSION>
   </ACCOUNT>
   <ACCOUNT id="22d2647740">
   <USERNAME>tuxemcon</USERNAME>
    <HOST>*</HOST>
    <PERMISSION>COPS</PERMISSION>
    </ACCOUNT>
  </ACL>
 </LADDER>
</AGENT>
EOF

my $twig = XML::Twig->new(
    twig_handlers => {ACCOUNT => \&acct}
);
$twig->parse($xmlstr);

sub acct {
    my ($t, $elt) = @_;
    print $elt->att('id'), "\n";
    print $elt->first_child('USERNAME'  )->text(), "\n";
    print $elt->first_child('HOST'      )->text(), "\n";
    print $elt->first_child('PERMISSION')->text(), "\n";
    print "\n";
}


__END__


4cf031986c
emcon
*sppcon*
CDOPS

b92794bbd7
cpemcon
*
COPS

8ff0478641
dbemcon
*
COPS

22d2647740
tuxemcon
*
COPS

[download]

Update: There is a great tutorial at http://web.archive.org/web/20080702002018/http://xmltwig.com (unfortunately, the tutorial link from XML::Twig seems to be down).

Update: using mirod's suggestion, and refactoring a little... 

sub acct {
    my ($t, $elt) = @_;
    print $elt->att('id'), "\n";
    for my $tag (qw(USERNAME HOST PERMISSION)) {
        print $elt->field($tag), "\n";
    }
    print "\n";
}

[download]

In reply to Re: XML::Twig Help by toolic
in thread XML::Twig Help by onegative

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.