Using BUILDARGS to avoid effects at a distance: 
{
   package Page;

   use strict;
   use warnings;

   use Moose;

   has 'url' => (
      is       => 'ro',
      isa      => 'Str',
      required => 1,
   );

   no Moose;
   __PACKAGE__->meta->make_immutable();
}

{
   package Container;

   use strict;
   use warnings;

   use Moose;

   my $pages_constraint = Moose::Util::TypeConstraints::create_paramet
+erized_type_constraint('ArrayRef[Page]');
   my $aoh_constraint   = Moose::Util::TypeConstraints::create_paramet
+erized_type_constraint('ArrayRef[HashRef]');

   around BUILDARGS => sub {
      my $orig  = shift;
      my $class = shift;
      my %args  = ( @_ == 1 ? %{ $_[0] } : @_ );

      if (exists($args{pages})) {
         my $pages = $args{pages};
         if (!$pages_constraint->check($pages)) {  # Need to coerce?
            if ($aoh_constraint->check($pages)) {  # Can we coerce?
               $args{pages} = [ map Page->new($_), @$pages ];
            }
         }
      }

      return $class->$orig(%args);
   };

   has 'pages' => (
      is      => 'rw',
      isa     => 'ArrayRef[Page]',
      default => sub { [ ] },
   );

   no Moose;
   __PACKAGE__->meta->make_immutable();
}

Container->new( pages => [ { url => "a" }, { url => "b" } ] );

[download]

This is basically the same approach you tried, but correctly uses the more appropriate BUILDARGS instead of BUILD.

Coded so it can take both ArrayRef[HashRef] and ArrayRef[Page].

In reply to Re^3: Moose from ArrayRef[HashRef] to ArrayRef[Object] by ikegami
in thread Moose from ArrayRef[HashRef] to ArrayRef[Object] by saintex

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.