If I understand your question correctly, your problem lies with the fact that your log entry sometimes breaks over two lines between the date and the time. Simply reading line by line will not cater for this; you have to detect whether the entry has gone onto a second line and do another readline inside the loop if so.

use strict;
use warnings;

open my $logFH, q{<}, \ <<EOD or die qq{open: <<HEREDOC: $!\n};
Script /opt/OV/bin/OpC/agtinstall/inst.sh invoked by root at 02/25/11
14:36:48
Other stuff here
Script /opt/OV/bin/OpC/agtinstall/inst.sh invoked by root at 02/25/11 
+14:36:48
more stuff
and more
Script /opt/OV/bin/OpC/agtinstall/inst.sh invoked by root at 02/25/11
14:36:48
more guff
EOD

my $rxDate = qr{(?x) ( (?:\d\d/){2}\d\d ) };
my $rxTime = qr{(?x) ( (?:\d\d:){2}\d\d ) };

while ( defined( my $line = <$logFH> ) )
{
    next unless $line =~
       m{(?x)
            ^
            Script \s
            \S+ \s
            invoked \s by \s root \s at \s
            $rxDate
            (?: \s $rxTime )?
        };
    my $date = $1;
    my $time =
       defined $2
       ? $2
       : do {
          defined( $line = <$logFH> )
             or die qq{Unexpected EOF\n};
          $line =~ $rxTime ? $1 : q{No time found};
          }; 
    my $timestamp = join q{ }, $date, $time;
    print qq{Timestamp: $timestamp\n};
}

close $logFH
   or die qq{close: <<HEREDOC: $!\n};

[download]

The output.

Timestamp: 02/25/11 14:36:48
Timestamp: 02/25/11 14:36:48
Timestamp: 02/25/11 14:36:48

[download]

I hope I have understood correctly and that this is helpful.

Cheers,

JohnGG

In reply to Re: Need help in data processing by johngg
in thread Need help in data processing by achak01

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.