It can be as simple as this:
use Modern::Perl;
use IO::All -strict;
use List::MoreUtils qw /each_array/;

my @first_array = io('./first.txt')->chomp->slurp;
my @second_array= io('./second.txt')->chomp->slurp;

my $ea = each_array( @first_array, @second_array );
while ( my ( $first, $second ) = $ea->() ) {
    if ( $first ne $second ) {
        say 'Arrays differ at line ', $ea->('index');
        say "First:  $first";
        say "Second: $second";
        last;
    }
}

[download]
It is simple and fast but not memory efficient as it reads in the whole files before starting to compare them.

This one is more memory efficient, but might be slower (depending on the length of the files and where the first difference is found):

use Modern::Perl;
use IO::All;

my $first_file  = io('./first.txt')->chomp  or die $!;
my $second_file = io('./second.txt')->chomp or die $!;

my $index = 0;
while ( my $first_line = $first_file->getline ) {
    my $second_line = $second_file->getline;
    if ( $first_line ne $second_line ) {
        say "Files differ at line $index";
        say "First:  $first_line";
        say "Second: $second_line";
        last;
    }
    $index++;
}

[download]

Update 1: added a more memory efficient version.

Update 2: used the slurp method in the first version.

CountZero

A program should be light and agile, its subroutines connected like a string of pearls. The spirit and intent of the program should be retained throughout. There should be neither too little or too much, neither needless loops nor useless variables, neither lack of structure nor overwhelming rigidity." - The Tao of Programming, 4.1 - Geoffrey James

In reply to Re: Beginner Hash Element Comparison by CountZero
in thread Beginner Hash Element Comparison by nicol004@uwp.edu

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.