This seems to be a good example for showing how a "simple regex solution" by itself just won't work -- you have to parse the data before doing anything with regexes to fix the spellings.

Here's a minimal solution using HTML::Parser. It would be worthwhile and instructive to use Unicode::Normalize as well, but if we're just twiddling umlauts, this is good enough. (Still, you'll want to check the output carefully...): 

#!/usr/bin/perl

use strict;
use HTML::Parser;

# set up a hash containing the umlauted characters and their replaceme
+nts:
my %replace = (
    "\xC4" => 'Ae', "\xCF" => 'Ie', "\xD6" => 'Oe', "\xDC" => 'Ue',
    "\xE4" => 'ae', "\xEF" => 'ie', "\xF6" => 'oe', "\xFC" => 'ue',
);
my $um = join '', keys %replace;

binmode STDIN, ':utf8';
binmode STDOUT, ':utf8';
$/ = undef;
my $input = <>;
my $output = '';

my $p = HTML::Parser->new( api_version => 3,
                           start_h => [ \&fix_umlaut, 'tagname, attr, 
+text' ],
                           default_h => [ \&copy, 'text' ],
    );
$p->empty_element_tags( 1 );
$p->parse( $input );

print $output;

sub fix_umlaut
{
    my ( $tagname, $attr, $text ) = @_;
    $output .= $text;
    if ( $tagname eq 'idx:orth' and $$attr{value} =~ /[$um]/ ) {
        $text =~ s/([$um])/$replace{$1}/g;
        $output .= $text;  # repeat the tag with modified umlauts
    }
}

sub copy
{
    $output .= $_[0];
}

[download]
That's set up to work as a "stdin - stdout filter" -- in other words, it's strictly a command line process, and the usage is supposed to be:  script_name < input.html > output.html

The HTML::Parser man page is well worth studying.

In reply to Re: Copy html tag and replace umlauts with alternate spellings by graff
in thread Copy html tag and replace umlauts with alternate spellings by Anonymous Monk

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.