Hi, you're welcome :)

You made it very easy as your question was very effective (How do I post a question effectively? , How do I compose an effective node title?).

Here is a similar approach using XML::Twig 

#!/usr/bin/perl --
#~ 2011-07-23-08:42:20+0000 by Anonymous Monk
#~ perltidy -csc -otr -opr -ce -nibc -i=4
use strict;
use warnings;
use autodie;    # dies if open/close... fail
use Data::Dumper;
use XML::Twig;

Main( @ARGV );
exit( 0 );

sub Main {
    Demo();
}

sub NotDemoMeaningfulName {
    my ($xml) = @_;
    my @data;
    my %site;
    my $t = XML::Twig->new(
        twig_handlers => {
            '//Site' => sub {
                warn $_->path;
                push @data, {%site} if %site;
                %site = ();
                $_->purge;    # free memory
            },
            '//Site/Id' => sub {
                warn $_->path;
                $site{Id} = $_->trimmed_text;
            },
            '//Site/Title' => sub {
                warn $_->path;
                $site{Title} = $_->trimmed_text;
            },
        },
    );
    $t->xparse($xml);
    $t->purge;
    return \@data;
} ## end sub NotDemoMeaningfulName

sub Demo {
    my $ref = NotDemoMeaningfulName( DemoData() );
    print Dumper($ref);
}

sub DemoData {

#~ http://perlmonks.com/?abspart=1;displaytype=displaycode;node_id=916
+054;part=1
    my $xml = <<'__XML__';
<Catalog>
  <Category>
    <Name>Arts &amp; Entertainment</Name>
    <Site>
      <Id>01-id...</Id>
      <Title>01-title...</Title>
    </Site>
    <Site>
      <Id>02-id...</Id>
      <Title>02-title...</Title>
    </Site>
  </Category>
</Catalog>
__XML__
    return $xml;
} ## end sub DemoData
__END__
$ perl xml.twig.916054.pl
/Catalog/Category/Site/Id at xml.twig.916054.pl line 30.
/Catalog/Category/Site/Title at xml.twig.916054.pl line 34.
/Catalog/Category/Site at xml.twig.916054.pl line 24.
/Catalog/Category/Site/Id at xml.twig.916054.pl line 30.
/Catalog/Category/Site/Title at xml.twig.916054.pl line 34.
/Catalog/Category/Site at xml.twig.916054.pl line 24.
$VAR1 = [
          {
            'Id' => '01-id...',
            'Title' => '01-title...'
          },
          {
            'Id' => '02-id...',
            'Title' => '02-title...'
          }
        ];

[download]

In reply to Re^3: parse xml and store data in array of hashesh by Anonymous Monk
in thread parse xml and store data in array of hashesh by osprofi

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.