chomp $_;
 my $line = $_;
 my @array =
  map {
   s/^\s+//;  # strip leading spaces
   s/\s+$//;  # strip tailing spaces
   $_         # return the modified string
  }
 split '\s+', $line;
[download]

You don't need anything this complicated.    Just do this:

 my @array = split;
[download]

 print @array."\n"; # prints number of elements instead of whole array
[download]

The concatenation operator (.) forces scalar context on its operands and an array in scalar context returns the number of elements in the array.    You need to use list context instead:

 print @array, "\n";
[download]

 $hash->{$line_num}=@array; # does not works because of previous issue
[download]

Again you are forcing scalar context on the array which evaluates to the number of elements in the array.    If you want to store the contents of the array then you have to either store a reference of the array:

 $hash->{ $line_num } = \@array;
[download]

or copy the array to an anonymous array.

 $hash->{ $line_num } = [ @array ];
[download]

In other words your while loop could be written more simply as:

while ( <FH> ) {
    $hash->{ $. } = [ split ];
}
[download]

But if you are using the line number as hash keys then you should probably be using an array instead of a hash.

my @data;
while ( <FH> ) {
    push @data, [ split ];
}
[download]

Or:

my @data = map [ split ], <FH>;
[download]

---

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.