Something like this maybe:

use warnings;
use strict;

my %ops;
my %opType = (W => 'Write', R => 'Read');

while (<DATA>) {
    next if ($. == 1);
    chomp;

    my ($date, $ip, $op, $hits, $file) = split /,\s*/;

    next if !exists $opType{$op};
    $ops{$opType{$op}}{$ip}{$file} += $hits;
}

report ($_, $ops{$_}) for 'Write', 'Read';


sub report {
    my ($type, $op) = @_;
    my @lines;

    print "\n\n\n";
    print "=======\n";
    print "${type}Operation \n";
    print "=======\n";

    for my $ip (keys %$op) {
        my $files = $op->{$ip};
        for my $file (keys %{$files}) {
            my $hits = $op->{$ip}{$file};
            push @lines, ["$ip - $file - $hits\n", $hits];
        }
    }

    print $_->[0] for sort {$a->[1] <=> $b->[1]} @lines;
}

__DATA__
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 4964,/export/file1.log
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 4964,/export/file2.log
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 4963,/export/file2.log
Sun Aug 21 12:08:21 2011,172.22.112.141, W, 9292,/export/home/another.
+file
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 4964,/export/file2.log
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 2493,/export/file1.log
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 2355,/export/another.log
Sun Aug 21 12:08:21 2011,172.22.32.28, R, 25,/export/another.log
Sun Aug 21 12:08:21 2011,172.20.220.38, W, 3699,/export/file2.log
Sun Aug 21 12:08:21 2011,172.20.220.146, W, 1996,<?>
Sun Aug 21 12:08:21 2011,172.22.32.28, W, 2776,/export/file1.log
Sun Aug 21 12:08:21 2011,172.22.32.28, R, 26,/export/file1.log

[download]

Prints:

=======
WriteOperation 
=======
172.20.220.146 - <?> - 1996
172.22.32.28 - /export/another.log - 2355
172.20.220.38 - /export/file2.log - 3699
172.22.32.28 - /export/file1.log - 5269
172.22.112.141 - /export/home/another.file - 9292
172.22.32.28 - /export/file2.log - 14891



=======
ReadOperation 
=======
172.22.32.28 - /export/another.log - 25
172.22.32.28 - /export/file1.log - 26

[download]

I've "cleaned up" the rest of your code too to remove code duplication and make the intent clearer (although I may have misunderstood some of the fields which actually makes the intent less clear!).

True laziness is hard work

In reply to Re: sort question by GrandFather
in thread sort question by roadtest

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.