that is to use the original array and splice/delete out the lines containing the usernames I want. But I couldn't figure out how to delete a row and then shift the rest up

I think splice and unshift are the tools for this job but the trick is to work your way forward from the end of the array so that you don't get indices tangled.

use strict;
use warnings;

use Data::Dumper;

my @records = (
   [ qw{ 922337219576856 rgiles 5005444 156 pts/220 9:00:44 } ],
   [ qw{ 922337219576856 mrandall 3309650 35 none 9:10:44 } ],
   [ qw{ 922337219576856 mmartin 4565899 122 pts/101 9:15:44 } ],
   [ qw{ 59761456123786 rkelly 5555555 999 pts/900 9:00:00 } ],
   [ qw{ 59761456123786 mvick 1234567 886 none 9:20:00 } ],
   [ qw{ 59761456123786 jrussel 7654321 456 tty/101 10:00:00 } ],
   [ qw{ 86555522211 cklien 5151515 000 tty/100 10:00:00 } ],
   [ qw{ 86555522211 mmartin 1234567 987 none 11:00:00 } ],
   );

my @excludeThese = qw{ rgiles mrandall rkelly mvick jrussel cklien };
my $rxExclude = do {
   local $" = q{|};
   qr{(?:@excludeThese)};
   };

my @excluded;
foreach my $idx ( reverse 0 .. $#records )
{
    unshift @excluded, splice @records, $idx, 1
       if $records[ $idx ]->[ 1 ] =~ $rxExclude;
}

print Data::Dumper->Dumpxs(
   [ \ @records, \ @excluded ],
   [ qw{ *records *excluded } ]
   );
[download]

The output.

@records = (
             [
               '922337219576856',
               'mmartin',
               '4565899',
               '122',
               'pts/101',
               '9:15:44'
             ],
             [
               '86555522211',
               'mmartin',
               '1234567',
               '987',
               'none',
               '11:00:00'
             ]
           );
@excluded = (
              [
                '922337219576856',
                'rgiles',
                '5005444',
                '156',
                'pts/220',
                '9:00:44'
              ],
              [
                '922337219576856',
                'mrandall',
                '3309650',
                '35',
                'none',
                '9:10:44'
              ],
              [
                '59761456123786',
                'rkelly',
                '5555555',
                '999',
                'pts/900',
                '9:00:00'
              ],
              [
                '59761456123786',
                'mvick',
                '1234567',
                '886',
                'none',
                '9:20:00'
              ],
              [
                '59761456123786',
                'jrussel',
                '7654321',
                '456',
                'tty/101',
                '10:00:00'
              ],
              [
                '86555522211',
                'cklien',
                '5151515',
                '000',
                'tty/100',
                '10:00:00'
              ]
            );
[download]

I hope this is helpful.

Cheers,

JohnGG

---

In reply to Re: Help to assign a 2D-Array to another while excluding specific rows. by johngg
in thread Help to assign a 2D-Array to another while excluding specific rows. by mmartin

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":

---

Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!

Titles consisting of a single word are discouraged, and in most cases are disallowed outright.

Read Where should I post X? if you're not absolutely sure you're posting in the right place.

Please read these before you post! —

• How do I compose an effective node title?
• How do I post a question effectively?
• Markup in the Monastery

Posts may use any of the Perl Monks Approved HTML tags:

a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr

You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)

	For:		Use:
	&		&
	<		&lt;
	>		&gt;
	[		&#91;
	]		&#93;

Link using PerlMonks shortcuts! What shortcuts can I use for linking?

See Writeup Formatting Tips and other pages linked from there for more info.