Which method are you talking about, with respect to those 5 seconds?  The XOR method outlined above takes just ~0.05 secs on my 4-year-oldish machine, for 10,000 comparisons against a common 40-char target (with ~3-5 deviations per sequence): 

my @set = qw(A T C G);
my $target = join "", map $set[rand @set], 1..40;
my @tests ;
for (1..10000) {
    my $test = $target;
    for (1..5) {
        substr($test, rand(length($target)), 1) = $set[rand @set];
    }
    push @tests, $test;
}


use Time::HiRes qw(time);
my $start = time();

my %change;  # reverse lookup table
for my $t1 (@set) {
    my $t = $t1;
    $t =~ tr/ATCG/HRDZ/;
    for my $t2 (@set) {
        $change{ $t ^ $t2 } = "$t1->$t2";
    }
}

$target =~ tr/ATCG/HRDZ/;

for my $test (@tests) {
    my $diff = $target ^ $test;
    while ($diff =~ /([^\x09\x06\x07\x1d])/g) {
        my $pos    = pos($diff);
        my $change = $change{$1};
        # do something with them...
    }
}

printf "%.3f secs\n", time() - $start;

__END__
0.052 secs

[download]

Storing away the results somewhere or doing something else with them will presumably take considerably longer than computing them...

In reply to Re^3: mismatching characters in dna sequence by Eliya
in thread mismatching characters in dna sequence by prbndr

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.