There is no need at all to use Tie anything for this task. As with many many problems that are attacked using Perl the key is to use a hash. There are bunch of newbie foibles in your code that are worth trying to clean up sooner rather than later. I haven't described the issues explicitly, but have addressed them in the following code. Have a try using the code as a starting point, and please ask about anything you don't understand:

#!usr/bin/perl 
use strict;
use warnings;

if (! @ARGV) {
    print <<HELP;
Usage:

> basecount.pl <bases file>

HELP
    exit;
}

open my $dnaIn, '<', $ARGV[0] or die "Can't open bases file $ARGV[0]: 
+$!\n";

my %counts;
my @baseList = qw(A T G C);

while (defined (my $line = <$dnaIn>)) {
    chomp $line;
    ++$counts{$_} for grep {/\S/} split '', $line;
}

my $bases;
my $errors;

$bases += $_ for @counts{@baseList};
$errors += $_ for map {$counts{$_}} grep {! /[ATGC]/} keys %counts;

print "Total bases: $bases\n";
print join (', ', map {"$_: $counts{$_}"} @baseList), "\n";
print "Errors: $errors\n" if $errors;

[download]

Note that the code is untested and in any case I may not have understood what you are counting.

True laziness is hard work

In reply to Re: Seeking help for using Tie : : File in my perl program for counting bases using Active Perl 5.10.1 Build 1007 by GrandFather
in thread Seeking help for using Tie : : File in my perl program for counting bases using Active Perl 5.10.1 Build 1007 by supriyoch_2008

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.