#!/usr/bin/perl

use strict;
use warnings;

use Net::OpenSSH::Parallel 0.12;
use Net::OpenSSH::Parallel::Constants qw(OSSH_ON_ERROR_IGNORE);

@ARGV == 3 or die <<EOU;
Usage:
  $0 host src_dir dst_dir

EOU

my ($host, $src, $dst) = @ARGV;

opendir my $dh, $src or die "unable to open $src";
my @ls = grep !/^\.{1,2}$/, readdir $dh;
close $dh;

my %now;
sub on_error {
    my ($pssh, $label, $error) = @_;
    warn "transfer of $now{$label} by $label failed\n";
    OSSH_ON_ERROR_IGNORE;
}

sub fetch_next {
    my ($pssh, $label) = @_;
    if (@ls) {
        my $file = shift @ls;
        $now{$label} = $file;
        warn "$label is copying $file\n";
        $pssh->push($label, rsync_put => "$src/$file", "$dst/$file");
        $pssh->push($label, sub => \&fetch_next);
    }
}

my $p = Net::OpenSSH::Parallel->new(on_error => \&on_error);

$p->add_host("worker$_", $host) for 1..5;
$p->all(sub => \&fetch_next);
$p->run;

[download]
Requires Net::OpenSSH::Parallel 0.12 I have just uploaded to CPAN.

In reply to Re^4: Fork multi processes by salva
in thread Fork multi processes by saurya1979

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.