It's not that complex. Just split your lines on tab characters, using split( /(\t)/, $line ). Those parens around \t make sure the tabs themself will be included in the elements of split, too. From there on, it's simple: print out every piece that's not a tab character, and keep track of how many characters you've printed so far. If you eventually do run into a tab character, you just print enough spaces to end up at a tab boundary. To make sure things keep running smoothly, you want to make sure that those spaces also count for the number of characters printed so far.

Still sounds complicated? This is all it takes.

use strict;
use warnings;

my @lines = map {s/@/\t/g; "$_\n"} split(/\n/, << 'EOF');
@foo bar baz quux
 @foo bar baz quux
foo@bar baz quux
foo @bar baz quux
foo bar@baz quux
foo bar @baz quux
EOF

my $tabwidth = 8;

for my $line (@lines) {
    my $pos = 0;
    for my $part (split/(\t)/,$line) {
        if ($part eq "\t") {
            my $spaces = " " x ($tabwidth - ($pos % $tabwidth));
            $pos += length($spaces);
            print $spaces;
        } else {
            $pos += length $part;
            print $part;
        }
    }
}
__END__
        foo bar baz quux
        foo bar baz quux
foo     bar baz quux
foo     bar baz quux
foo bar baz quux
foo bar         baz quux

[download]

In reply to Re: regex'ing source code by muba
in thread regex'ing source code by zuma53

Title:
Use:  <p> text here (a paragraph) </p>
and:  <code> code here </code>
to format your post, it's "PerlMonks-approved HTML":


  • Posts are HTML formatted. Put <p> </p> tags around your paragraphs. Put <code> </code> tags around your code and data!
  • Titles consisting of a single word are discouraged, and in most cases are disallowed outright.
  • Read Where should I post X? if you're not absolutely sure you're posting in the right place.
  • Please read these before you post! —
  • Posts may use any of the Perl Monks Approved HTML tags:
    a, abbr, b, big, blockquote, br, caption, center, col, colgroup, dd, del, details, div, dl, dt, em, font, h1, h2, h3, h4, h5, h6, hr, i, ins, li, ol, p, pre, readmore, small, span, spoiler, strike, strong, sub, summary, sup, table, tbody, td, tfoot, th, thead, tr, tt, u, ul, wbr
  • You may need to use entities for some characters, as follows. (Exception: Within code tags, you can put the characters literally.)
            For:     Use:
    & &amp;
    < &lt;
    > &gt;
    [ &#91;
    ] &#93;
  • Link using PerlMonks shortcuts! What shortcuts can I use for linking?
  • See Writeup Formatting Tips and other pages linked from there for more info.